Big Earth Datacube Standards: Coverages, WCS, WCPS on rasdaman

OGC WCPS 1.1 Coverage Constructor
"Human-Centric Text, Without Encoding Garbage"

The Use Case:

Creating a d-dimensional coverage with non-grid index CRS (e.g. EPSG:4326) for some d≥1.

OGC WCPS 1.1 adds coverage constructor syntax particularly streamlined with the modern coverage standard OGC CIS 1.1 aka ISO 19123-2. This WCPS enhancement, which is also adopted into ISO 19123-3 and OGC Abstract Topic 6.3, One can see this constructor as a textual, human readable description of a coverage "without the encoding garbage". The so-called xWcps constructor allows defining an n-D coverage by customizing domain set, range type, range set, and metadata through expressions.

The service:

Below we present some examples showing xWcps in action.

Example 1 - The expression below computes a 256-bucket histogram over band b of some coverage $c of unknown domain extent and dimension

for $c in (AvgTemperatureColorScaled)
let $subset := [ ansi("2015-07-01"), Lat(60:75.5), Long(80.5:155.5) ]
return 
    encode(
        coverage GeneralGridCoverage histogram
        domain set crs "OGC:Index1D" with bucket index (0:255)
        range type grey quantity unsigned long
        range set count( $c[$subset].Red = bucket )
        , "json"
    )

Example 2 - The expression below creates a 2D geo-referenced coverage decoded() from an input TIFF file submitted as a positional parameter in WCPS query. The demo will download the tiff file from this link and submit it along with the WCPS example query when you click on the "Run Query" button.

for $c in (world_temp_high_res)
let $tmpCov :=
  coverage x
  domain crs "EPSG:4326" with
    lat regular (-90:90) resolution -0.4,
    lon regular (-180:180) resolution 0.4
  range type
    red   quantity unsigned char,
    green quantity unsigned char,
    blue  quantity unsigned char
  range set
    decode($1)
return
  encode( $tmpCov * log($c) , "image/png" )

Example 3 - The expression below creates a 1-D temporal coverage; for each timeslice it contains the summary of values (calculated by general condenser) from the original coverage $c corresponding to that timeslice

for $c in (AvgTemperatureColorScaled)
return
  encode(
    coverage AverageTemperature
    domain crs "OGC:AnsiDate" with
      t irregular ( domain( $c, ansi ) )
    range type
      grey quantity int
    range set
        condense +
        over $plat lat( domain( $c[Lat(40.5:42.5)], Lat ) ),
	     $plon lon( domain( $c[Lon(35.5:45.5)], Lon ) )
        using $c[ Lat($plat), Lon($plon), ansi(t) ].Red
    , "json"
  )

Example 4 - The expression below applies a 3x3 matrix (created as a coverage constant) as a Sobel filter on a 2-D grid-indexed coverage.

for $c in (NIR)
let $k :=
  coverage Sobel3x3
  over $px i ( -1 : +1 ), $py j ( -1 : +1 )
  values < 1; 2; 1; 0; 0; 0; -1; -2; -1 >
return 
  encode(		
    coverage FilteredImage
    domain crs "OGC:Index2D" with
      x index (50 : 600), 
      y index (250 : 650)
    range type grey quantity int
    range set 
        condense + 
        over $pi i(-1 : 1), $pj j(-1 : 1)
        using $c[ i(x + $pi), j(y + $pj) ].red * $k[ i($pi), j($pj) ]
    , "image/png"
  )